abednarz.net

Bed's Stuff

Thu 01 January 2009

Turning a protected RTSP stream into an iTunes PodCast (with linux and OSX)

Posted by bed in Tech Talk   

A friend of mine does a radio show interstate that interests me. Unfortunately, being a late night show (midnight) and interstate, for me to listen to this live would require me being awake at 4am or so. Due to record label copyright permissions, this show is not available as a podcast download - its only available for live or delayed streaming. Undeterred, I wanted to automatically grab the stream and make it available on my iPhone for listening when it suited me, while out and about.

Getting the stream as a file with linux

The availability of the delayed stream, means this problem can be tackled with a cronjob on my gentoo linux server. This particular stream is served with the Real Time Streaming Protocol which means all we really need is the live555 media libraries. For Gentoo this was as easy as issuing "emerge live" as root on the commandline. For Ubuntu this would be "apt-get install liblivemedia-utils".

Then its as simple as calling openRTSP with the stream url. ie:

openRTSP -4 -a -t -d 3900 rtsp://streaming.server.com.au:80/streaming.server.com.au/name.mp4 1>name.mp4

This will write the audio stream  as a file.

The next step is to automate this process with a script being launched by cron. In this case, the name of the stream is in the format radioshow_YY_MM_DD.mp4. So my script will grab today's stream.
radioshow.sh:

1
2
3
#!/bin/sh
filename="radioshow_"`eval date +%Y-%m-%d`".mp4"
openRTSP -a -t -4 -d 7300 rtsp://streaming.server.com.au:80/streaming.server.com.au/$filename > /mnt/download/radioshow/$filename

Since this show is a weekly one, my crontab is setup to download the stream at 1:30pm every thursday.

crontab line: #download behind the mirror every thursday at 1:30pm 30 13 * * 4 /home/bed/radioshow.sh

Converting to a PodCast with OSX

Once we have the files, I wanted to put it in my iTunes library flagged as a PodCast. A commandline tool AtomicParsley enables us to set the appropriate mp4 tags so iTunes sees the file as a PodCast, however AtomicParsley doesn't like the mp4 tags created by openRTSP. To get around this we can load our file in QuickTime, and then re-export it to mp4. This will now be a file with mp4 tags that AtomicParsley can modify. We can then execute the following command:

AtomicParsley name.mp4 --podcastFlag true --artist name --title name --advisory explicit --description name --podcastURL name --podcastGUID 1 --year "2008-12-25" --overWrite

This will create a new file, which we can then drag into iTunes. This will now show up as a proper PodCast, so it will automatically sync to my iPhone and then be removed once I've listened to it.

Now that's a fair bit of manual mucking around, so we can use AppleScript to automate all of this in one nice move, which can be the scheduled with launchd to occur at a convenient time:

-- This script does the following:
-- + looks in a directory in my file server and copies it file locally,
-- + loads it into quick time, and exports it to add proper tags
-- + sets podcast tags with AtomicPasley
-- + imports it into iTunes
-- + cleans up files

mount volume "afp://bedentoo/download" as user name "XXXXXXXX" with password "YYYYYYYYY"
tell application "Finder"
    repeat until ((name of every disk contains "download") as boolean)
        delay 2
    end repeat
end tell

set source_location to "download:radioshow"

tell application "Finder"
    set new_file to {get name of files of folder source_location} as text
    with timeout of 7200 seconds --2 hour timeout, incase we're copying over a VPN or something
        copy {file new_file of folder source_location} to desktop
    end timeout
end tell

-- Use QuickTime to export it (to set proper mp4 tags)
set user to do shell script "whoami"
set local_new_file to {"/Users/" & user & "/Desktop/" & new_file} as text
set local_fixed_file to {"/Users/" & user & "/Desktop/" & new_file & ".fixed.mp4"} as text
tell application "QuickTime Player"
    activate
    close every window
    open local_new_file
    with timeout of 1800 seconds -- half hour timeout incase export takes a while
        export front document to local_fixed_file as MPEG4 using default settings
    end timeout
end tell
quit application "QuickTime Player"

-- our file is always the format of ccccccccccccccccYYYY-MM-DD.mp4 so lets extract the date
copy characters 17 through 26 of new_file as string to datestamp

-- run AtomicParsley (located in ~/scripts/) to flag it as a podCast
set run_ap to {"/Users/" & user & "/scripts/AtomicParsley " & local_fixed_file & " --podcastFlag true --artist radioshow --title 'radioshow '" & datestamp & " --advisory explicit --album radioshow --description radioshow --podcastURL 'http://www.url.au/shows/radioshow' --podcastGUID 1234 --year '" & datestamp & "' --overWrite"} as text
do shell script run_ap

-- import file into iTunes
tell application "iTunes"
    activate
    add ({POSIX file local_fixed_file})
end tell

--cleanup!
tell application "Finder"
    delete {POSIX file local_new_file}
    delete {POSIX file local_fixed_file}
    delete {file new_file of folder source_location}
end tell

Lastly, the applescript is saved as an .app and scheduled with launchd via lingon, which runs at 8am friday morning.